spongeLayer_radial_polyn5_for_treeids Function

private function spongeLayer_radial_polyn5_for_treeids(me, treeIds, tree, nDim, n) result(res)

This function calculates the sigma for the radial spongelayer polynomial order 5 from treeids. Sponge profile: where, \sigma_A - sponge strength, L - thickness, x0 - start of sponge.

Profile is taken from: Xu, Hui; Sagaut, Pierre (2013): Analysis of the absorbing layers for the weakly-compressible lattice Boltzmann methods. In Journal of Computational Physics 245, pp. 14-42. DOI: 10.1016/j.jcp.2013.02.051.

Arguments

Type IntentOptional Attributes Name
type(tem_spongeLayer_radial_type) :: me

Spatial sponge layer to evaluate
integer(kind=long_k), intent(in) :: treeIds(n)

treeIds of elements in given level
type(treelmesh_type), intent(in) :: tree

global treelm mesh
integer, intent(in) :: nDim

Dimension
integer, intent(in) :: n

Number of arrays to return

Return Value real(kind=rk), (n)

return value


Source Code

  function spongeLayer_radial_polyn5_for_treeids(me, treeids, tree, nDim, n) &
    &                                     result(res)
    ! --------------------------------------------------------------------------
    !> Spatial sponge layer to evaluate
    type(tem_spongeLayer_radial_type) :: me
    !> Number of arrays to return
    integer, intent(in) :: n
    !> global treelm mesh
    type( treelmesh_type ), intent(in) ::tree
    !> treeIds of elements in given level
    integer(kind=long_k), intent(in) :: treeIds(n)
    !> Dimension
    integer, intent(in) :: nDim
    !> return value
    real(kind=rk) :: res(n)
    ! --------------------------------------------------------------------------
    integer :: i
    real(kind=rk) :: rad, outer_radius, sigma, vec(3), coord(3)
    real(kind=rk) :: const_fac
    ! --------------------------------------------------------------------------

    outer_radius = me%radius + me%thickness
    vec = 0.0_rk
    const_fac = 3125_rk/(256_rk*me%thickness**5)

    do i = 1,n
      !barycentric coordinate
      coord = tem_BaryOfId( tree, treeIds(i) )
      vec(1:nDim) = coord(1:nDim) - me%origin(1:nDim)
      rad = sqrt( vec(1)**2 + vec(2)**2 + vec(3)**2 )
      if (rad > me%radius .and. rad < outer_radius) then
        sigma = const_fac * (outer_radius - rad) * (rad - me%radius)**4
        res(i) = sigma * me%dampFactor
      else if (rad > outer_radius) then
        res(i) = me%dampFactor
      else
        res(i) = 0.0_rk
      end if
    end do

  end function spongeLayer_radial_polyn5_for_treeids